10 REM 64/128 LOAN AMORTIZATION PROGRAM
20 REM BY JAAP KROES
30 REM 03/86
40 PRINT"[147]":POKE53280,0:POKE53281,0:POKE646,7
50 A$="64/128 LOAN AMORTIZATION PROGRAM"
60 GOSUB90:A$="BY  JAAP  KROES"
70 GOSUB90:A$=" BOX 66,  PELLA, IA. 50219"
80 GOSUB90:FORT=1TO1000:NEXTT:GOTO140
90 A%=LEN(A$):Y=A%
100 PRINT"":FORX=1TOA%
110 PRINTTAB((39-A%)/2)MID$(A$,Y,X)"[157][145]"
120 Y=Y-1:FORD=1TO25:NEXTD:NEXTX:RETURN
140 PRINT"[147]"
150 PRINTSPC(12)"L O A N  M E N U"
160 PRINTSPC(11)"1) MONTHLY PAYMENT"
170 PRINTSPC(11)"2) LOAN BALANCE (PAYOFF)"
180 PRINTSPC(11)"3) AMORTIZE A LOAN":PRINTSPC(11)"4) END PROGRAM"
190 GETA$:IFA$=""THEN190
200 IFA$<"1"ORA$>"4"THEN190
210 ONVAL(A$)GOTO220,350,500,840
220 PRINT"[147]     M O N T H L Y  P A Y M E N T":PRINT
230 INPUT"      1) LOAN PRINCIPLE ";LP
240 INPUT"      2) LOAN INTEREST  ";LI
250 IR=LI/12
260 INPUT"      3) LOAN DURATION (MONTHS)";LD:PRINT
270 X=(1-(1+IR/100)^-LD)/(IR/100)
280 MP=LP/X:MR=INT(MP/0.01)*0.01
290 MR$=STR$(MR+.001):MR$=MID$(MR$,2,(LEN(MR$)-2))
300 PRINT"      4) MONTHLY PAYMENT = $";MR
310 PRINT"              ANOTHER   Y/N   [146]"
320 GETA$:IFA$<>"Y"ANDA$<>"N"THEN320
330 IFA$="N"THENRUN140
340 IFA$="Y"THENRUN220
350 PRINT"[147] L O A N  B A L A N C E  ( P A Y O F[160]F[160])":PRINT
360 INPUT"    WHAT IS THE LOAN AMOUNT";PV
370 INPUT"    WHAT IS THE PAYMENT AMOUNT";PMT
380 INPUT"    HOW MANY PAYMENTS MADE";N
390 INPUT"    WHAT IS THE INTEREST RATE";I
400 RI=I/12
410 X=(RI/100)+1:Y=X^N:Z=Y*PV
420 XX=X*PMT:ZZ=Y-1:YY=RI/100:ZX=ZZ/YY:ZY=XX*ZX:BA=Z-ZY
430 BL=INT(BA/0.01)*0.01
440 BL$=STR$(BL+.001):BL$=MID$(BL$,2,(LEN(BL$)-2))
450 PRINT"    REMAINING BALANCE IS ";BL$
460 PRINT"              ANOTHER Y/N  [146]"
470 GETA$:IFA$<>"Y"ANDA$<>"N"THEN470
480 IFA$="N"THENRUN140
490 IFA$="Y"THENRUN350
500 PRINT"[147]"
510 PRINTSPC(3)"L O A N  A M O R T I Z[160]A T I O N"
520 INPUT"     AMOUNT OF LOAN---$";A:I=A
530 INPUT"     INTEREST RATE IN %";B
540 INPUT"     DURATION OF LOAN IN MONTHS";C
550 PRINT"    DO YOU WANT HARD COPY (Y/N)"
560 GETZ$:IFZ$<>"Y"ANDZ$<>"N"THEN560
570 Z=0:IFZ$="Y"THENZ=1:GOTO590
580 PRINT"[147]":PRINT" #    PMT       INT     PRIN       BAL  "
590 PRINT:Y=1
600 D=A/(((1-(1+B/1200)^-C)/(B/1200)))
610 E=B/1200*A:F=D-E:G=A-F:GOSUB620:GOTO720
620 DD=INT(D/0.01)*0.01
630 EE=INT(E/0.01)*0.01
640 FF=INT(F/0.01)*0.01
650 GG=INT(G/0.01)*0.01
660 DD$=STR$(DD+.001):DD$=MID$(DD$,2,(LEN(DD$)-2))
670 EE$=STR$(EE+.001):EE$=MID$(EE$,2,(LEN(EE$)-2))
680 IFEE<1THENEE$="0"+STR$(EE+.001):EE$=MID$(EE$,2,(LEN(EE$)-2))
690 FF$=STR$(FF+.001):FF$=MID$(FF$,2,(LEN(FF$)-2))
700 GG$=STR$(GG+.001):GG$=MID$(GG$,2,(LEN(GG$)-2)):IFGG<=0THENGG$="0.00"
710 RETURN
720 IFZ=1THENPRINT"[147]":PRINTTAB(13)" PLEASE  WAIT [146]"
725 IFZ=1THENPRINTTAB(13)"   PRINTING   [146]":GOTO880
730 PRINTY:PRINTTAB(11-LEN(DD$))"[145]"DD$:PRINTTAB(20-LEN(EE$))"[145]"EE$
740 PRINTTAB(28-LEN(FF$))"[145]"FF$:PRINTTAB(39-LEN(GG$))"[145]"GG$
750 C=C-1:A=G:Y=Y+1
760 IFC>0THEN600
765 GOSUB770:GOTO800
770 T=VAL(DD$):TT=T*(Y-1):TC=TT-I:CT=INT(TC/0.01)*0.01:TL=INT(TT/0.01)*0.01
780 TT$=STR$(TL+.001):TT$=MID$(TT$,2,(LEN(TT$)-2))
790 TC$=STR$(CT+.001):TC$=MID$(TC$,2,(LEN(TC$)-2)):RETURN
800 PRINT"TOTAL PAYMENTS = "TT$:PRINT"TOTAL COST     =  "TC$
810 IFC=0THENPRINT"              ANOTHER Y/N   [146]"
820 GETA$:IFA$<>"Y"ANDA$<>"N"THEN820
830 IFA$="Y"THENRUN500
840 PRINT"[145]             END PROGRAM Y/N   [146] "
850 GETA$:IFA$<>"Y"ANDA$<>"N"THEN850
860 IFA$="N"THENRUN140
870 IFA$="Y"THENA$="* * *  T[160]H[160]A[160]N K  Y O U[160][160]* * *":PRINT"[147]":GOSUB90
875 PRINT"[144]":END
880 REM *** PRINTER ROUTINE ***
890 E$=CHR$(27):H$=CHR$(9)
900 OPEN4,4:CMD4
910 PRINT
920 PRINT"                   **** LOAN AMORTIZATION SCHEDULE ****"
930 PRINT
940 PRINT"           AMOUNT OF LOAN     = $"A
950 PRINT"           INTEREST RATE      =  "B"%"
960 PRINT"           LENGTH OF LOAN     =  "C"MONTHS"
970 PRINT:K=0:P=1:Y=1
980 PRINT"  PMNT #        PMNT          INTEREST        PRINCIPAL      BALANCE"
990 PRINT
1000 D=A/(((1-(1+B/1200)^-C)/(B/1200)))
1010 E=B/1200*A:F=D-E:G=A-F:GOSUB620
1020 Y$=STR$(Y)
1030 PRINT#4,""TAB(5-LEN(Y$))Y$;
1040 PRINT#4,""TAB(16-LEN(DD$))DD$;
1050 PRINT#4,""TAB(16-LEN(EE$))EE$;
1060 PRINT#4,""TAB(16-LEN(FF$))FF$;
1070 PRINT#4,""TAB(16-LEN(GG$))GG$
1080 C=C-1:A=G:K=K+1:Y=Y+1
1090 IFK=42THEN1150
1100 IFC>0THEN1000
1110 GOSUB770:CMD4
1120 PRINT:PRINT"  TOTAL PAYMENTS = "TT$
1130 PRINT:PRINT"             TOTAL COST = "TC$
1140 IFC=0THENPRINT#4:CLOSE4:PRINT"[147]":GOTO810
1150 CMD4:P=P+1:PRINT:PRINT"        CONTINUED ON NEXT PAGE":K=0
1155 FORT=1TO8:PRINTCHR$(10):NEXT
1160 PRINT"                                   PAGE #"P:PRINT:PRINT:PRINT
1170 PRINT"  PMNT #        PMNT          INTEREST        PRINCIPAL     BALANCE"
1180 PRINT
1190 GOTO1100